pxMagnetGetPositionZ#(mdata)

Параметры

mdata% - магнит

Описание

Возвращает позицию Z магнита.

Смотрите так же

    Команды установки параметров:
pxMagnetSetPosition

Пример

;Пример использования функции
;pxMagnetGetPositionZ

Graphics3D 800,600,32,2
SetBuffer BackBuffer()

;Организуем физический мир с плоскостью
pxCreateWorld(1)
pxSetGravity(0, -20, 0)
;Визуализируем плоскость
plane=CreatePlane( )
EntityColor plane,0,100,200

camera=CreateCamera()
light=CreateLight()
PositionEntity camera,40,65,-70
RotateEntity camera,30,30,0

;Поставим фигуры
For i=-2 To 2
    For j=-2 To 2
        Create_Px_Stack(15, 18*i,0.1,18*j)
    Next
Next

x = 0;
y =1
z = -10

;Создаем магнит
magnit = pxCreateMagnet(1, 0, 10000)
;Установим максимальный радиус действия магнита
pxMagnetSetMaxRadius(magnit, 85)
;Создадим визуальное отображение магнита
sp =CreateSphere ()
EntityColor sp,255,0,0 ;цвет будет красным
PositionEntity sp,x,y,z

While Not KeyDown( 1 )
;Расчет физического мира
    RenderPhysic(40,0)
;Обновим позиции всех тел
    Update_Px_Cube()

    If KeyDown (205) x = x+1
    If KeyDown (203) x = x-1
    If KeyDown (200) z = z+1
    If KeyDown (208) z = z-1
    If KeyHit(57) pxMagnetActivate(magnit, 0, 1)
;обновим позиции магнита и сферы
    pxMagnetSetPosition(magnit, x, y, z)
    PositionEntity sp, x,y,z

    UpdateWorld ()
    RenderWorld
    Text 10,10,"Клавищи курсора - управляют положением магнита"
    Text 10,20,"Пробел - активирует магнит"
    Text 10,30,"X позиция магнита " + pxMagnetGetPositionX(magnit)
    Text 10,40,"Y позиция магнита " + pxMagnetGetPositionY(magnit)
; -------------------- применяем pxMagnetGetPositionZ
    Text 10,50,"Z позиция магнита " + pxMagnetGetPositionZ(magnit)

    Flip
Wend

End

;В примере понадобся много однотипных тел
Type Px_Cube
    Field cube_body%
    Field cube_mesh%
End Type

;Создает линейку кубиков
Function Create_Px_Stack(size%, pos_x, pos_y, pos_z)
    CubeSize = 1
    Spacing = 0.01
    pos_y = pos_y+CubeSize
    While size
        ocu.Px_Cube = New Px_Cube
;Создаем физический кубик
        ocu\cube_body=PxCreateCube(CubeSize ,CubeSize ,CubeSize , 10)
;Устанавливаем в позицию
        pxSetPosition(ocu\cube_body,pos_x,pos_y,pos_z)
;Визуализируем его мешем блица
        ocu\cube_mesh = CreateCube()
        ScaleEntity ocu\cube_mesh, CubeSize ,CubeSize ,CubeSize
        EntityColor ocu\cube_mesh,Rand(0,255),Rand(0,255),Rand(0,255)
        kil=kil+1
        k=k+1

        pos_y = pos_y +(CubeSize * 2.0 + Spacing)
        size=size-1
    Wend
End Function

;Обновляет позиции всех кубиков
Function Update_Px_Cube()
    For ocu.Px_Cube = Each Px_Cube
        pxSetEntity(ocu\cube_mesh, ocu\cube_body)
    Next
End Function

К содержанию

Нажмите здесь чтобы увидеть последнюю версию этой странички в режиме online.